Магнитные карты и ПК - [20]

_{2120 IF C$="01101" THEN PRINT "6";}

_{2130 IF C$="11100" THEN PRINT "7";}

_{2140 IF C$="00010" THEN PRINT "8";}

_{2150 IF C$="10011" THEN PRINT "9";}

_{2999 RETURN}

_{3000 REM (c)1996 Patrick GUEULLE}

Эта программа абсолютно идентична LECTISO2, но она дает несколько более громоздкие результаты.

ПРОГРАММЫ ПРЕОБРАЗОВАНИЯ

Файлы с расширением .CAR, полученные с помощью LECT75 и LECT210, естественно, не вызывают никаких проблем совместимости с программами данной книги. Однако это не всегда получается при их использовании в другом контексте, что, конечно, вправе сделать любой из наших читателей.

Ниже приводятся несколько весьма полезных служебных программ для решения небольших проблем, которые рано или поздно могут появиться.

Программа выравнивания

Как уже показывалось, наши программы считывания магнитных дорожек создают линейные — однострочные, то есть без специальных символов перехода на новую строку, — файлы с расширением .CAR. Это нисколько не мешает их отображению, например с помощью команды ТУРЕ операционной системы DOS, но может возникнуть желание их распечатать или сохранить в более удобном формате.

Для этого вместо программы текстового редактора более практично, по нашему мнению, использовать небольшую программу JUSTCAR.ВAS, трансформирующую любой файл .CAR в строго упорядоченный блок из 32 колонок.

_{10 REM — JUSTCAR. BAS —}

_{20 KEY OFF: CLS}

_{30 PRINT "имя файла?";}

_{40 INPUT N$: IF N$="" THEN END}

_{50 FOR F=1 TO LEN(N$)}

_{60 IF MID$(N$,F,1) = "." THEN 90}

_{70 NEXT F}

_{80 N$=N$+".CAR"}

_{90 OPEN NS: FOR INPUT AS #1}

_{100 OPEN "carte.bak" FOR OUTPUT AS #2}

_{110 DIM M(LOF(1)): CLS}

_{120 L=0: WHILE NOT EOF(1)}

_{130 INPUT#1,M(L)}

_{140 PRINT#2,M(L);: L=L+1}

_{150 WEND}

_{160 CLOSE #1}

_{170 OPEN NS FOR OUTPUT AS #1}

_{180 G=0: FOR F=0 TO L-1}

_{190 PRINT M(F);}

_{200 IF M(F)=1 THEN PRINT#1,"1";}

_{210 IF M(F)=0 THEN PRINT#1,"0";}

_{220 G=G+1: IF G=32 THEN PRINT#1, G=0}

_{230 NEXT F: PRINT}

_{240 END}

_{250 REM COPYRIGHT (c) 1996 Patrick GUEULLE}

Отметим, что аварийный файл CARTE.ВАК был создан прежде всего для сохранения данных в случае сбоя, происшедшего во время обработки (разрыв сети и т. д.).

Кроме того, если имя исходного файла содержит расширение .CAR, у нас не будет необходимости его набирать, поскольку оно добавится автоматически.

В результате работы программы преобразованные данные заменяют содержимое исходного файла, при этом новый файл, хотя уже и выровненный, остается совместимым с программами данной книги.

Ниже показано, что получается при обработке файла TEST5.CAR с помощью программы JUSTCAR.

Программа инвертирования

Большинство считывающих устройств, начиная с описанных в данной главе, ожидают прохода карты в строго определенном направлении — как правило, это слева направо перед головкой. Иногда приходится проводить карту в обратном направлении (справа налево) или работать с нестандартными картами, записанными наоборот.

Программа INVERT.BAS способна «перевернуть» любой файл .CAR вне зависимости от его длины.

_{10 REM — INVERT.BAS —}

_{20 KEY OFF: CLS}

_{30 PRINT "имя файла, который следует перевернуть?"}

_{40 INPUT N$: IF N$="" THEN END}

_{50 FOR F=1 TO LEN(NS)}

_{60 IF MID$ (N$,F,1)="." THEN 90}

_{70 NEXT F}

_{80 N$=N$+".CAR"}

_{90 OPEN N$ FOR INPUT AS #1}

_{100 OPEN "carte.bak" FOR OUTPUT AS #2}

_{110 DIM M(LOF(1)): CLS}

_{120 L=0: WHILE NOT EOF (1)}

_{130 INPUT #1,M(L)}

_{140 PRINT#2,M(L);: L=L+1}

_{150 WEND}

_{160 CLOSE #1}

_{170 OPEN N$ FOR OUTPUT AS #1}

_{180 FOR F=L-1 TO 0 STEP -1}

_{190 PRINT M(F);}

_{200 IF M(F)=1 THEN PRINT#1,"1";}

_{210 IF M(F)=0 THEN PRINT#1,"0";}

_{220 NEXT F: PRINT}

_{230 END}

_{240 REM COPYRIGHT (c)1997 Patrick GUEULLE}

Ниже представлен результат, полученный с помощью файла-образца TEST5.CAR.

Программа преобразования в формат .CRD

Автор этой книги, естественно, не единственный в мире любитель магнитных карт, тем более что этот «вид спорта» особенно популярен в США. За океаном предпочтение отдают файлам формата .CRD,который отличается от .CAR отсутствием пробелов.

Поскольку в Internet можно встретить интересные программы, использующие формат .CRD, нам показалось полезным снабдить читателей служебной программой, способной сделать файлы .CAR совместимыми с ними. Речь идет о программе CARTOCRD.BAS.

В том виде, в котором она написана, эта небольшая программа может преобразовать файл CARTE.CAR, который был только что считан, в файл CARTE. CRD.

_{10 REM — CARTOCRD.BAS —}

_{20 CLS: KEY OFF}

_{30 PRINT "Преобразование файла CARTE.CAR в CARTE.CRD"}

_{40 OPEN "carte.car" FOR INPUT AS #1}

_{50 OPEN "carte.crd" FOR OUTPUT AS #2}

_{60 IF EOF(1) THEN 110}

_{70 INPUT #1,A}

_{80 IF A=1 THEN PRINT#2,"1";}

_{90 IF A=0 THEN PRINT#2,"0";}

_{100 GOTO 60}

_{110 PRINT "Выполнено": BEEP}

_{120 END}

_{130 REM (c) 1996 Patrick GUEULLE}

Ниже показано, во что превращается файл TEST5.CAR, обработанный программой CARTOCRD.BAS (сначала его надо скопировать под именем CARTE .CAR).

Программа импорта файлов

Служебная программа CRDTOCAR.BAS осуществляет обратную операцию по отношению к предыдущей. Иначе говоря, выполняет преобразование файла CARTE.CRD в CARTE.CAR, совместимый со всеми нашими остальными программами.

_{10 REM — CRDTOCAR.BAS —}

_{20 CLS: KEY OFF}

_{30 PRINT "Преобразование файла CARTE.CRD в CARTE.CAR"}

_{40 OPEN "carte.crd" FOR INPUT AS #1}

_{50 OPEN "carte.car" FOR OUTPUT AS #2}